TheGameCreators - CodeBase

Return to the CodeBase listing

Category: 3D Effects

Version: 1.0

Information

Uploaded: 31st Aug 2003 12:44

Modified: 31st Aug 2003 12:44

Author: Rob K

Summary

Effective motion blur technique. Works with static and animated objects. Media attached.

Full Description

Motion blur technique which uses alpha mapping and cloned objects to create a blurring effect. <br /> <br /> See commented source code.

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

`Motion Blur Demo

`================

`Motion Blur effect works with animated and static objects

`currently can only handle one motion blurred object at a time,

`if you want to improve this, add another dimension to the BlurPos array

`and turn the BlurTimer variable into an array.

`Functions:

`EnableMotionBlur(ObjectNo,No. of blur frames,ObjectNo of first blur frame)

`>> Clones objects and sets up effect

`UpdateMotionBlur(ObjectNo,No. of blur frames,ObjectNo of first blur frame,Delay)

`>> Updates the blur effect if the object has been moved / rotated

`>> the Delay variable sets the delay in time between each frame

`ChangeMotionBlurAnim(ObjectNo,No. of blur frames,Object No of first blur frame,PlayState,StartFrame,EndFrame)

`>> Call this when you change the animation of the object

`PlayState 0 = No Anim

`PlayState 1 = Playing Anim

`PlayState 2 = Looping Anim

`StartFrame and EndFrame specify the start and end of the animation

`HideMotionBlur(ObjectNo,No. of blur frames,ObjectNo of first blur frame)

`>> Disables effect, does not delete blue objects

`ShowMotionBlur(ObjectNo,No. of blur frames,ObjectNo of first blur frame)

`>> Re-enables effect

`Motion Blur Globals, put at top of program

`==========================================

Dim BlurPos(5,6)

global BlurTimer

rem best display

if check display mode(1024,768,32)=1

set display mode 1024,768,32

endif

rem init

sync on : sync rate 60

rem floor

load image "alienfloor.jpg",2

make matrix 1,1000,1000,3,3

position matrix 1,-500,0,-500

prepare matrix texture 1,2,1,1

randomize matrix 1,5.0

update matrix 1

rem load object

load object "alienalien.x",1

rotate object 1,0,10,0

loop object 1

rem texture object

load image "alienalien_gn.bmp",3

set object smoothing 1,100

texture object 1,3

rem camera

xrotate camera 270

move camera 100

xrotate camera 0

move camera 200

rem light

set shadow shading on 1

set point light 0,100,200,-300

set light range 0,2000

startx = Object Position X(1)

starty = Object Position Y(1)

startz = Object Position Z(1)

yrotate object 1,90

`Enable blur on object 1, with 5 frames, using objects 11 to 16

EnableMotionBlur(1,5,10)

rem loop

k$=inkey$()

if k$="s" then stop object 1 : desc$="STOPPED" : ChangeMotionBlurAnim(1,5,10,0,0,0)

if k$="h" then HideMotionBlur(1,5,10)

if k$="v" then ShowMotionBlur(1,5,10)

if spacekey() then move object 1,-2

if object in screen(1)=0 then position object 1,startx,starty,startz

rem Display prompt

center text screen width()/2,50,"SPACE TO MOVE.  S to STOP ANIM.  H to HIDE EFFECT, V to SHOW EFFECT"

`Update the blur effect

UpdateMotionBlur(1,5,10,30)

rem Update screen

sync

rem end loop

loop

function EnableMotionBlur(ObjectNo,BlurObjects,FirstObjectNo)

for i=1 to BlurObjects

currobj=FirstObjectNo+i

if object exist(currobj)=0

Clone Object currobj,ObjectNo

Set Alpha Mapping On currobj,100-((100/BlurObjects)*i)

if object looping(ObjectNo) then loop object currobj : Set Object Frame currobj,Object Frame(ObjectNo)-i

endif

next i

endfunction

function HideMotionBlur(ObjectNo,BlurObjects,FirstObjectNo)

for i=1 to BlurObjects

currobj=FirstObjectNo+i

Hide Object currobj

next i

endfunction

function ShowMotionBlur(ObjectNo,BlurObjects,FirstObjectNo)

for i=1 to BlurObjects

currobj=FirstObjectNo+i

Show Object currobj

next i

endfunction

function UpdateMotionBlur(ObjectNo,BlurObjects,FirstObjectNo,UpdateDelay)

TimeDiff = Timer()-BlurTimer

If TimeDiff > UpdateDelay

BlurTimer = Timer()

for i=BlurObjects to 1 step -1

for z=0 to 5

BlurPos(i,z) = BlurPos(i-1,z)

next z

next i

BlurPos(1,0) = Object Position X(ObjectNo)

BlurPos(1,1) = Object Position Y(ObjectNo)

BlurPos(1,2) = Object Position Z(ObjectNo)

BlurPos(1,3) = Object Angle X(ObjectNo)

BlurPos(1,4) = Object Angle Y(ObjectNo)

BlurPos(1,5) = Object Angle Z(ObjectNo)

for i=1 to BlurObjects

currobj=FirstObjectNo+i

Position Object currobj,BlurPos(i,0),BlurPos(i,1),BlurPos(i,2)

Rotate Object currobj,BlurPos(i,3),BlurPos(i,4),BlurPos(i,5)

next i

Endif

endfunction

function ChangeMotionBlurAnim(ObjectNo,BlurObjects,FirstObjectNo,Play,StartFrame,EndFrame)

for i=1 to BlurObjects

currobj = FirstObjectNo+i

Select Play

Case 0

Stop Object currobj

Set Object Frame currobj,Object Frame(ObjectNo)

Endcase

Case 1

Play Object currobj,StartFrame,EndFrame

Set Object Frame currobj,Object Frame(ObjectNo)

Endcase

Case 2

Loop Object currobj,StartFrame,EndFrame

Set Object Frame currobj,Object Frame(ObjectNo)

Endcase

Endselect

next i

endfunction

Download

Please login to download

Comments

No comments yet.

CodeBase - Motion Blur

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments

Author Name:	Rob K
CodeBase Entries:	5