TheGameCreators - CodeBase - TrueSky Simulator

Category: Miscellaneous

Version: 1.01

Information

Uploaded: 22nd Aug 2008 02:15

Modified: 22nd Aug 2008 04:25

Author: The Sab

Summary

Sky simulator. Controls a unique path for the sun and up to four moons, as well as day/twilight/night transitions. Adjustable viewer latitude and individual ecliptic for each orbital object.

Full Description

I started working on this before the RTS add-on came out, so I kept working on it. Each orbital object has a unique path with adjustable orbit length, revolution length, ecliptic, size, and distance from viewer. User must pass object and image numbers to each individual object. If an object already exists with that number, it will put that object in orbit, otherwise a default sphere with appropriate stats will be created and assigned to that object number. Changing the Latitude will accurately adjust the movement of all orbits. Calls must be made to the functions InitializeTrueSky(), CreateSky(ObjNo1, ObjNo2, ImgNo1, ImgNo2, Distance1, Distance2) and CreateOrbital(0, _SUN, ObjNo, ImgNo, DayLength, YearLength, Size, Degrees of Ecliptic) as all the timing functions are based on the sun, a.k.a. Orbital 0. Function TrueSky() must be called in the Main Loop. There are several features which I still wish to add, such as sun glow, planetary rings, and some other graphic tweaks, but I am still learning the graphic side of Dark Basic Pro. Also be aware that this program is making several sine and cosine calculations for each orbital, so it might eat up a bit of processor power. The code has pretty good notes and instructions, but let me know if anything is confusing or not working properly. Also, all textures that I used are too large to post here, but all were in .png format.

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

`***********************************

`*** True Sky Simulator, V1.01   ***

`*** By Bernard Sabatini         ***

`***********************************

#constant _SUN 1

#constant _MOON 2

#constant _RING 3

function InitializeTrueSky()

`*** Global variables used by TrueSky ***

global Latitude as float               `Observer's latitude

global CosLat as float                 `Store latitude's cosine for lighter calculation

global SinLat as float                 `Store latitude's sine for lighter calculation

global StartTime as float              `This is the variable used by the timing system

global NightSkyObject as integer       `Storage for the night sphere object

global DaySkyObject as integer

global NightSkyImage as integer        `Storage for the night sphere image

global DaySkyImage as integer

global NightSkyDistance as integer     `Radius of the sky sphere

global DaySkyDistance as integer

global TwilightAngle as integer        `Angle when twilight starts

global SinTwilight as float            `Sine of twilight angle, for lighter calculation

global dim OrbitType(5) as byte        `Currently 1 for sun, 2 for moon.  3 will be for a ring when i figure out how

global dim ObjNumber(5) as integer     `Orbits object number

global dim ImgNumber(5) as integer     `Orbits image number

global dim OrbitLen(5) as integer      `Length of the Orbit's 'day' in seconds

global dim OrbitRev(5) as integer      `Length of the Orbit's 'year' in 'days'

global dim OrbitRSec(5) as integer     `Length of the Orbit's 'year' in seconds

global dim OrbitDis(5) as integer      `Distance of Orbit from observer

global dim OrbitSize(5) as integer     `Size of the Orbit object

global dim OrbitTime(5) as float       `Current time of Orbit's day in seconds

global dim OrbitTDPS(5) as float       `The Degrees per second of the Orbit's day

global dim OrbitDate(5) as float       `Current date of Orbit's year in seconds

global dim OrbitDDPS(5) as float

global dim OrbitEcl(5) as float

global dim OrbitInc(5) as float

global dim OrbitTAng(5) as float

global dim OrbitX(5) as float

global dim OrbitY(5) as float

global dim OrbitZ(5) as float

global dim GameTime(5) as float

global dim DisplayHour(5) as integer

global dim DisplayMinute(5) as integer

global dim DisplaySecond(5) as integer

endfunction

function TrueSky()

`*** Update the game timer ***

interval# = timer() - StartTime

StartTime = timer()

for i = 0 to 4

`*** Update positions of sun and moon objects ***

if OrbitType(i) = _SUN or OrbitType(i) = _MOON

OrbitTime(i) = OrbitTime(i) + (interval#/1000.0)

OrbitDate(i) = OrbitDate(i) + (interval#/1000.0)

if OrbitTime(i) > OrbitLen(i)

OrbitTime(i) = OrbitTime(i) - OrbitLen(i)

endif

if OrbitDate(i) > OrbitRSec(i)

OrbitDate(i) = OrbitDate(i) - OrbitRSec(i)

endif

`*** Update Time Angle ***

OrbitTAng(i) = wrapvalue(OrbitTime(i) * OrbitTDPS(i))

GameTime(i) = OrbitTAng(i)/15

DisplayHour(i) = int(GameTime(i))

DisplayMinute(i) = int((GameTime(i)-DisplayHour(i))*60)

DisplaySecond(i) = int((((GameTime(i)-DisplayHour(i))*60)-DisplayMinute(i))*60)

`*** Update Inclination for day ***

OrbitInc(i) = OrbitEcl(i) * sin(wrapvalue(OrbitDate(i) * OrbitDDPS(i)))

`*** Calculate Solar and Lunar Coordinates ***

OrbitX(i) = sin(OrbitTAng(i)) * cos(OrbitInc(i))

OrbitY(i) = (CosLat * cos(OrbitInc(i)) * -cos(OrbitTAng(i))) + (SinLat * sin(OrbitInc(i)))

OrbitZ(i) = (cos(OrbitTAng(i)) * cos(OrbitInc(i)) * SinLat) + (CosLat * sin(OrbitInc(i)))

`*** Position object in sky and center sky on viewing camera

position object ObjNumber(i), (OrbitX(i) * OrbitDis(i)) + camera position x(), (OrbitY(i) * OrbitDis(i)) + camera position y(), (OrbitZ(i) * OrbitDis(i)) + camera position z()

endif

`*** Update solar specific items as well as skysphere objects ***

if OrbitType(i) = _SUN

`*** Rotate and center the sky on the camera***

xrotate object NightSkyObject, -wrapvalue(Latitude - 90.0)

yrotate object NightSkyObject, wrapvalue(OrbitTAng(i)-90)

position object NightSkyObject, camera position x(), camera position y(), camera position z()

position object DaySkyObject, camera position x(), camera position y(), camera position z()

`*** Set sunlight to proper angle

set directional light 0, -OrbitX(i), -OrbitY(i), -OrbitZ(i)

`*** Adjust sky fades to proper level to match sun height ***

dayFade = ((OrbitY(i) / SinTwilight + 1)) * 50

if dayFade < 0

dayFade = 0

endif

if dayFade > 100

dayFade = 100

endif

print dayFade

set alpha mapping on DaySkyObject, dayFade

set ambient light (dayFade/4 + 10)

endif

`*** Update moon specific values ***

if OrbitType(i) = _MOON

`*** Ensure face of moon always faces Earth ***

yrotate object ObjNumber(i), OrbitTAng(i)

endif

next i

endfunction

function SetLatitude(lat as float)

if lat >= -90 and lat <= 90

Latitude = lat

CosLat = cos(Latitude)

SinLat = sin(Latitude)

else

set cursor 100, 100

print "Latitude must be between -90 and 90.  No change made."

wait key

endif

endfunction

function StartTimer()

StartTime = timer()

endfunction

function CreateOrbital(Onum as integer, Otype as byte, Objnum as integer, Imgnum as integer, Olen as integer, Orev as integer, Osize as integer, Oecl as float)

if (Onum = 0 and Otype <> _SUN) or (Onum <> 0 and Otype = _SUN)

set cursor 100, 100

print "Orbit '0' is the only Sun orbit allowed.  Binary stars not yet permitted because I don't know how they work."

wait key

else

OrbitType(Onum) = Otype

ObjNumber(Onum) = Objnum

ImgNumber(Onum) = Imgnum

OrbitLen(Onum) = Olen

OrbitRev(Onum) = Orev

OrbitRSec(Onum) = Orev * Olen

OrbitDis(Onum) = 20000 + ((4 - Onum) * 3000)

OrbitSize(Onum) = Osize

OrbitTime(Onum) = 0.0

OrbitTDPS(Onum) = 360.0 / Olen

OrbitDate(Onum) = 0.0

OrbitDDPS(Onum) = 360.0 / (Orev * Olen)

OrbitEcl(Onum) = Oecl

OrbitTAng(Onum) = 0.0

CreateOrbitalObject(Onum)

endif

endfunction

function CreateOrbitalObject(Onum as integer)

if object exist(ObjNumber(Onum)) = 0

If OrbitType(Onum) = 1      `If object is a sun

make object sphere ObjNumber(Onum), OrbitSize(Onum), 16, 16

texture object ObjNumber(Onum), ImgNumber(Onum)

color object ObjNumber(Onum), rgb(255,255,0)

set object emissive ObjNumber(Onum), rgb(255, 255, 0)

endif

If OrbitType(Onum) = 2      `If object is a moon

make object sphere ObjNumber(Onum), OrbitSize(Onum), 16, 16

texture object ObjNumber(Onum), ImgNumber(Onum)

set object ambience ObjNumber(Onum), rgb(255, 255, 255)

set object rotation zyx ObjNumber(Onum)

xrotate object ObjNumber(Onum), -wrapvalue(Latitude-90)

endif

`If OrbitType(Onum) = 3     `If object is a ring

`make object plain ObjNumber(Onum), OrbitSize(Onum), OrbitSize(Onum)

`texture object ObjNumber(Onum), ImgNumber(Onum)

`xrotate object ObjNumber(Onum), Latitude

`endif

endif

endfunction

function CreateSky(dayobj as integer, nightobj as integer, dayimg as integer, nightimg as integer, daydis as integer, nightdis as integer)

`*** Delete any objects using the newly assigned numbers ***

if object exist(dayobj)

delete object dayobj

endif

if object exist(nightobj)

delete object nightobj

endif

`*** Store the new data in the global variables ***

DaySkyObject = dayobj

NightSkyObject = nightobj

DaySkyImage = dayimg

NightSkyImage = nightimg

DaySkyDistance = daydis

NightSkyDistance = nightdis

`*** Make day sphere ***

make object sphere DaySkyObject, DaySkyDistance * 2, 32, 32       `This sphere is static and does not rotate

set object cull DaySkyObject, 0                                   `Make it visible from the inside

texture object DaySkyObject, DaySkyImage                          `Texture with blue sky image

set object light DaySkyObject, 0                                  `Don't want shadows on the sphere

set object transparency DaySkyObject, 2                           `Set transparency for day/night transition

`*** Make night sphere ***

make object sphere NightSkyObject, NightSkyDistance * 2, 32, 32   `This sphere rotates along the equator at the same rate as the sun

set object cull NightSkyObject, 0                                 `Make it visible from the inside

texture object NightSkyObject, NightSkyImage                      `Texture with starry sky image

set object light NightSkyObject, 0                                `Don't want shadows on the sphere

set object rotation zyx NightSkyObject                            `Adjust rotation so the sky spins correctly...

xrotate object NightSkyObject, -wrapvalue(Latitude - 90.0)          `...with the proper latitude

endfunction

`*********************************************************

`*** Set Functions ***************************************

`*********************************************************

function SetDaySkyObject(objnum as integer)

if object exist(DaySkyObject)

delete object DaySkyObject

endif

DaySkyObject = objnum

CreateSky(objnum, NightSkyObject, DaySkyImage, NightSkyImage, DaySkyDistance, NightSkyDistance)

endfunction

function SetNightSkyObject(objnum as integer)

if object exist(NightSkyObject)

delete object NightSkyObject

endif

NightSkyObject = objnum

CreateSky(DaySkyObject, objnum, DaySkyImage, NightSkyImage, DaySkyDistance, NightSkyDistance)

endfunction

function SetDaySkyImage(imgnum as integer)

DaySkyImage = imgnum

CreateSky(DaySkyObject, NightSkyObject, imgnum, NightSkyImage, DaySkyDistance, NightSkyDistance)

endfunction

function SetNightSkyImage(imgnum as integer)

NightSkyImage = imgnum

CreateSky(DaySkyObject, NightSkyObject, DaySkyImage, imgnum, DaySkyDistance, NightSkyDistance)

endfunction

function SetDaySkyDistance(skydis as integer)

DaySkyDistance = skydis

CreateSky(DaySkyObject, NightSkyObject, DaySkyImage, NightSkyImage, skydis, NightSkyDistance)

endfunction

function SetNightSkyDistance(skydis as integer)

NightSkyDistance = skydis

CreateSky(DaySkyObject, NightSkyObject, DaySkyImage, NightSkyImage, DaySkyDistance, skydis)

endfunction

function SetTwilightAngle(twiang as integer)

TwilightAngle = twiang

SinTwilight = sin(twiang)

endfunction

function SetOrbitType(Onum as integer, Otype as byte)

if Otype >= _SUN and Otype <= _RING

OrbitType(Onum) = Otype

else

set cursor 100, 100

print "Invalid Orbit Type."

wait key

endif

endfunction

function SetObjectNumber(Onum as integer, Objnum as integer)

ObjNumber(Onum) = Objnum

CreateOrbitalObject(Onum)

endfunction

function SetImageNumber(Onum as integer, Imgnum as integer)

ImgNumber(Onum) = Imgnum

texture object ObjNumber(Onum), ImgNumber(Onum)

endfunction

function SetOrbitLen(Onum as integer, Olen as integer)

OrbitLen(Onum) = Olen

OrbitRSec(Onum) = OrbitRev(Onum) * OrbitLen(Onum)

OrbitTDPS(Onum) = 360 / OrbitLen(Onum)

OrbitDDPS(Onum) = 360 / OrbitRSec(Onum)

endfunction

function SetOrbitRev(Onum as integer, Orev as integer)

OrbitRev(Onum) = Orev

OrbitRSec(Onum) = OrbitRev(Onum) * OrbitLen(Onum)

OrbitTDPS(Onum) = 360 / OrbitLen(Onum)

OrbitDDPS(Onum) = 360 / OrbitRSec(Onum)

endfunction

function SetOrbitSize(Onum as integer, Osize as integer)

OrbitSize(Onum) = Osize

endfunction

function SetOrbitTime(Onum as integer, Otime as float)

if Otime <= OrbitLen(Onum) and Otime >= 0

OrbitTime(Onum) = Otime

else

set cursor 100, 100

print "Time must be between 0 and orbit length of: ", OrbitLen(Onum), ".  No change made."

wait key

endif

endfunction

function SetOrbitDate(Onum as integer, Odate as float)

if Odate * OrbitLen(Onum) <= OrbitRSec(Onum) and Odate >= 0

OrbitDate(Onum) = Odate * OrbitLen(Onum)

else

set cursor 100, 100

print "Date must be between 0 and orbit revolution of: ", OrbitRev(Onum), ".  No change made."

wait key

endif

endfunction

function SetOrbitEcl(Onum as integer, Oecl as float)

if Oecl >= -90 or Oecl <= 90

OrbitEcl(Onum) = Oecl

else

set cursor 100, 100

print "Ecliptic must be between -90 and 90.  No change made."

wait key

endif

endfunction

`*********************************************************

`*** Get Functions ***************************************

`*********************************************************

function GetLatitude#()

lat# = Latitude

endfunction lat#

function GetDaySkyObject()

dayobj = DaySkyObject

endfunction dayobj

function GetNightSkyObject()

nightobj = NightSkyObject

endfunction nightobj

function GetDaySkyImage()

dayimg = DaySkyImage

endfunction dayimg

function GetNightSkyImage()

nightimg = NightSkyImage

endfunction nightimg

function GetDaySkyDistance()

daydistance = DaySkyDistance

endfunction daydistance

function GetNightSkyDistance()

nightdistance = NightSkyDistance

endfunction nightdistance

function GetTwilightAngle()

twiang = TwilightAngle

endfunction twiang

function GetOrbitType(Onum as integer)

Otype = OrbitType(Onum)

endfunction Otype

function GetObjNumber(Onum as integer)

Objnum = ObjNumber(Onum)

endfunction Objnum

function GetImgNumber(Onum as integer)

Imgnum = ImgNumber(Onum)

endfunction Imgnum

function GetOrbitLen(Onum as integer)

Olen = OrbitLen(Onum)

endfunction Olen

function GetOrbitRev(Onum as integer)

Orev = OrbitRev(Onum)

endfunction Orev

function GetOrbitRSec(Onum as integer)

Orsec = OrbitRSec(Onum)

endfunction Orsec

function GetOrbitDis(Onum as integer)

Odis = OrbitDis(Onum)

endfunction Odis

function GetOrbitSize(Onum as integer)

Osize = OrbitSize(Onum)

endfunction Osize

function GetOrbitTime(Onum as integer)

Otime# = OrbitTime(Onum)

endfunction Otime#

function GetOrbitTDPS(Onum as integer)

Otdps# = OrbitTDPS(Onum)

endfunction Otdps#

function GetOrbitDate(Onum as integer)

Odate# = OrbitDate(Onum)

endfunction Odate#

function GetOrbitDDPS(Onum as integer)

Oddps# = OrbitDDPS(Onum)

endfunction Oddps#

function GetOrbitEcl(Onum as integer)

Oecl = OrbitEcl(Onum)

endfunction Oecl

function GetOrbitInc(Onum as integer)

Oinc# = OrbitInc(Onum)

endfunction Oinc#

function GetOrbitTAng(Onum as integer)

Otang# = OrbitTAng(Onum)

endfunction Otang#

function GetOrbitX(Onum as integer)

Ox# = OrbitX(Onum)

endfunction Ox#

function GetOrbitY(Onum as integer)

Oy# = OrbitY(Onum)

endfunction Oy#

function GetOrbitZ(Onum as integer)

Oz# = OrbitZ(Onum)

endfunction Oz#

function GetGameTime(Onum as integer)

GT# = GameTime(Onum)

endfunction GT#

function GetDisplayHour(Onum as integer)

DH = DisplayHour(Onum)

endfunction DH

function GetDisplayMinute(Onum as integer)

DM = DisplayMinute(Onum)

endfunction DM

function GetDisplaySecond(Onum as integer)

DS = DisplaySecond(Onum)

endfunction DS

Download

Please login to download

Comments

No comments yet.

Author Name:	The Sab
CodeBase Entries:	10

CodeBase - TrueSky Simulator

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments