TheGameCreators - CodeBase - Tombstone City - game from the 80's now in DBPro

Return to the CodeBase listing

Category: 2D

Version: 0.14

Information

Uploaded: 14th May 2013 22:08

Modified: 15th May 2013 00:02

Author: CSL

Summary

DBPRo version of Tombstone City, from the Texas Instruments TI-99/4A 16-bit home computer of the 80's

Full Description

Create a new project, use your preferred name. Download and unzip media files inside the project folder. Files should reside in sub-folder named media. Copy and paste my code into the project. Compile and run. Video tutorial of game play can be found here -> http://youtu.be/c66sYlBTlBA Leave comments in YouTube or drop me an email [email protected] I hope you enjoy playing it as much as I enjoyed developing it.

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

`*********************

`*                   *

`*  Tombstone City   *

`*    11/19/2010     *

`*    21:45 EST      *

`*      v 0.14       *

`*                   *

`*********************

` 0.11 - 11/15/2010 - Added F1 option to restart game.

` 0.12 - 11/16/2010 - Changed to random tumbleweed spawns, renamed ShipInsideGrid to a more generic InsideGrid function

` 0.13 - 11/19/2010 - Media enhancements

` 0.14 - 05/09/2013 - Fixed joystick input, added joystick deadzone, changed screen layout

`**********************

set display mode 640,480,32

SET WINDOW ON : SET WINDOW LAYOUT 0,0,0 : MAXIMIZE WINDOW

HIDE MOUSE

global GameRelease$ = "v 0.14"

cls

sync on

`sync rate 0

`set display mode 640,480,32

`set window on

`set window size 640,480

set text font "Verdana"

set text size 12

ink 0,0

hide mouse

` *** Type declarations ***

type xycoords

tcxx as integer

tcyy as integer

mactive as integer

msprnum as integer

endtype

type tumbleweed

twx as integer

twy as integer

twsprnum as integer

active as integer

endtype

type direction

dx as integer

dy as integer

endtype

type sprtype

sprnum as integer

available as integer

endtype

type bkcolortype

bkred as integer

bkgreen as integer

bkblue as integer

endtype

type gridtype

xc as integer

yc as integer

blocked as integer

endtype

` **** Constants ****

#constant bonuspoints 1000                                              ` Bonus points when level is completed

#constant numlives 9                                                    ` Number of lives at the beginning of the game (the game adds 1 before starting)

#constant begframe 1                                                    ` Beginning frame # morg animated sprite

#constant endframe 6                                                    ` Ending frame # morg animated sprite

#constant morgframespd 75                                               ` Sprite frame changing speed (milliseconds)

#constant mltp  16                                                      ` Multiplier - establishes rate of movement in pixels

#constant weeds 30                                                      ` Max number of tumbleweeds allowed on screen

#constant maxmorgs 10                                                   ` Max number of enemies allowed on screen

#constant maxpairs 37                                                   ` Max number of tombstone pairs at the beginning of a level

#constant morgvalue 150                                                 ` Scoring value morg (enemy)

#constant tweedvalue 100                                                ` Scoring value tumbleweed

#constant panicpenalty 1000                                             ` Scoring penalty when teleporting (panic button)

#constant bulltcspd  10                                                 ` Bullet speed

#constant shipsprite 1                                                  ` Sprite # ship

#constant bullsprite 18                                                 ` Sprite # bullet

#constant gridsprnum 50                                                 ` Beginning sprite # grid block

#constant twsprbeg 101                                                  ` Beginning sprite # tumbleweed

#constant morgsprbeg 201                                                ` Beginning sprite # morg

#constant tssprbeg 301                                                  ` Beginning sprite # tombstone

#constant upangle 0                                                     ` Ship angle of rotation

#constant rightangle 90                                                 ` Ship angle of rotation

#constant downangle 180                                                 ` Ship angle of rotation

#constant leftangle 270                                                 ` Ship angle of rotation

#constant spawnsound 1                                                  ` Ship spawn sound #

#constant shotsound 2                                                   ` Shooting sound #

#constant diesound 3                                                    ` Ship killed sound #

#constant enemymovesound 4                                              ` Morg moving sound #

#constant gamesound 5                                                   ` Background music sound # - v0.13 11/19/2010

#constant shpimg 1                                                      ` Ship image #

#constant blockimg 2                                                    ` Safe zone grid block image #

#constant bullimg 3                                                     ` Bullet image #

#constant tmbstoneimg 4                                                 ` Tombstone image #

#constant morgimg 5                                                     ` Morg image #

#constant twimg 6                                                       ` Tumbleweed image #

#constant xsize 16                                                      ` Horizontal sprite size

#constant ysize 16                                                      ` Vertical sprite size

#constant minx 1                                                        ` Left screen boundary

#constant miny 3                                                        ` Top of screen boundary

#constant shotrate 100                                                  ` Rate of fire in milliseconds, ship

#constant hired 255                                                     ` Tombstone highlight color (R)

#constant higreen 0                                                     ` Tombstone highlight color (G)

#constant hiblue 0                                                      ` Tombstone highlight color (B)

#constant countdown 30000                                               ` Countdown to speed up the last morg left on screen - to avoid leeching

#constant maxtclevel 9                                                  ` Used to limit enemy speed increases on each level

#constant twleech 75                                                    ` Max number of tweeds allowed to be shot down before leeching occurs

` **** End Constants ****

global spawndiff

global maxtweeds = twleech : inc maxtweeds, 15                          ` Program will stop spawning tumbleweeds after player has killed 'maxtweeds' tumbleweeds

global twshot                                                           ` # of tweeds shot down on level

global maxspd

global elapsed : global hrs : global mnts : global secs                 ` Level elapsed time

global ctdntimr

global bdred : global bdgreen : global bdblue

global xoffst : global yoffst                                           ` Sprite x,y offsets

global maxx : global maxy                                               ` Screen boundaries, bottom and right

global tssprend : global gridblkend : global tssprdel : global twsprend ` Other sprite # variables

global tcscore = 0: global tclevel : global tclives = numlives : global tcday = 0 ` Game play variables

global leftx : global rightx : global topy : global bottomy                  ` Grid corner coords

global tctimer : global morgtctimer : global twtctimer : global bullettimer : global newtimer : global shottimer  ` Timer variables

global twostctimer : global spawntimer : global gametimer                                                         ` Timer variables

global morgtcspd : global tcspd : global twtcspd     ` Milliseconds timer to control speed of game sprites - lower = faster

global seconds : global flashtime                                       ` seconds = time between morg spawns; flashtime = time to start flashing grid, alerting a morg is about to spawn

global tsmodx : global tsmody : global ddy : global ddx: global tsmdx : global tsmdy : global tsmgx : global tsmgy      ` Delta variables

global y : global x                                                     ` Ship's x & y coords

global xth = 0 : global yth = -1                                        ` Ship's x,y pointing direction

global morgnum                                                          ` Morg on screen count

global twonscreen                                                       ` Tumbleweed on screen count

global oldangle = 0 : global angle = 0                                  ` Ship angle of direction

global sprred : global sprgreen : global sprblue                        ` Tombstone sprite's RGB values

global gsprred : global gsprgreen : global gsprblue                     ` Grid sprite's RGB values

` **** Other variables ****

global bkcc

global highspr

global modx : global mody : global mdx : global mdy : global tsdx : global tsdy

global movexy : global result : global cityck

global yscan : global xscan

global morgck

global paironex : global paironey : global pairtwox : global pairtwoy

global morgidx : global widx                ` Loop indexes

maxx = int(screen width() / mltp)           ` if width = 640, maxx = 40  (columns)

maxy = int(screen height() / mltp)          ` if height = 480, maxy = 30  (rows)

global highx : global highy                 ` Coordinates of highlighted tombstone (when morg is about to spawn)

` *** Flags ***

global gamerestarted = 0                    ` Flag activates when game is restarted

global pairfound                            ` To indicate if a tombstone pair was found

global completed                            ` To indicate if the whole screen has been scanned for tombstone pairs

global exitblocked                          ` To indicate if all the safe zone grid exits are blocked by tombstones

global onemorgflag = 0                      ` Flag to indicate when one enemy remains - for leeching routine

global panicbtn                             ` Teleport (panic) flag (when Return or B button is pushed)

global diepanic = 0                         ` Flag when calling panic() function after ship is caught

global startlevel = 0                       ` Indicates if a new level is about to start

` *** Arrays ****

dim tweed(weeds) as tumbleweed              ` Array to keep track of tumbleweeds

dim grid(16) as xycoords                    ` Array to keep track of the safe zone grid in the middle of the screen

dim around(8) as direction                  ` Stores all possible x,y directions (0,-1, 1,-1, 1,0,... etc.)

dim morg(maxmorgs) as xycoords              ` Array to keep track of all enemies (morgs)

dim morgsprite(maxmorgs) as sprtype         ` Array to manage pool of sprite #s to asssign to morg

dim tcity(maxx,maxy)                        ` Screen map for tombstones, grid blocks and tumbleweeds

dim bkcolor(50) as bkcolortype              ` Selection of screen background colors

dim gridexit(12) as gridtype                ` Stores the coordinates of the safe-zone grid exits

` ****

dec maxx : dec maxy,2

LoadMedia()                                 ` Load sprite images, sound effects, etc.

InitArrays()

DisplayGrid()                               ` Display safe zone grid

gsprred = sprite red(gridsprnum)            ` Stores original grid block colors

gsprgreen = sprite green(gridsprnum)

gsprblue = sprite blue(gridsprnum)

LoadBkColors()                              ` Selects a random screen background color

StartNewLevel()                             ` Start a new level

REM **** Begin Main Loop ****

KeyJoystick()

MoveShip()

SpawnMorg()

Movemorg()

MoveTweed()

GameTimeUpdate()

DisplayText()

sync

loop

REM **** End Main Loop ****

function KeyJoystick()

xth = 0 : yth =0

if upkey() or joystick up()

yth = -1

xth = 0

angle = upangle

else

if downkey() or joystick down()

yth = 1

xth = 0

angle = downangle

else

if rightkey() or joystick right()

xth = 1

yth = 0

angle = rightangle

else

if leftkey() or joystick left()

xth = -1

yth = 0

angle = leftangle

else

if spacekey() or joystick fire a()

if timer() > shottimer + shotrate      ` Establish rate of auto-fire

Shooting()

xth = 0

yth =0

shottimer = timer()

endif

else

if returnkey() or joystick fire b()

panicbtn = 1

Panic()

endif

endfunction ` KeyJoystick

function MoveShip()

if timer() >= tctimer + tcspd

if oldangle <> angle

rotate sprite shipsprite,angle

oldangle=angle

tctimer = timer()

else

ddx = xth : ddy = yth : cityck = tcity(x + ddx, y + ddy)

if cityck > 0 then exitfunction

if xth

if x + ddx >= maxx then x = maxx else if x + ddx <= minx then x = minx else x = x + ddx

endif

if yth

if y + ddy >= maxy then y = maxy else if y + ddy <= miny then y = miny else y = y + ddy

endif

tctimer = timer()

endif ` if oldangle ...

endif ` if newtimer ...

sprite shipsprite,x * mltp,y * mltp,shpimg

ShipCollision()

endfunction ` MoveShip()

function ShipCollision()

for i = 1 to maxmorgs

if morg(i).mactive

if x =  morg(i).tcxx and y = morg(i).tcyy

diepanic = 1

panic()

exitfunction

endif

next i

endfunction ` ShipCollision

function SpawnMorg()

if morgnum = 1 and onemorgflag = 0

if NoMorePairs()

ctdntimr = timer()                         ` Start countdown to speed up last morg left, when no tombstone pairs remain.

onemorgflag = 1

endif

if timer() > spawntimer + flashtime * 1000        ` Check when to start warning flash

ChangeColorGrid(hired, higreen, hiblue)       ` Flash grid block with warning color

SelectPair()                                  ` Find a tombstone pair and highlight the tombstone that will spawn the morg

if timer() > spawntimer + seconds * 1000      ` Check when to actually spawn morg

ChangeColorGrid(gsprred, gsprgreen, gsprblue) ` Reset grid block colors back to normal

if pairfound

onemorgflag = 0

for i = 1 to 8                              ` ... look for an empty space to spawn

tsdx = around(i).dx

tsdy = around(i).dy

if tcity(highx + tsdx, highy + tsdy) = 0 and NoMorgsAround()                                                    ` If space around tombstone is empty

if not ((((highx + tsdx >= leftx) and (highx + tsdx <= rightx)) and ((highy + tsdy >= topy) and (highy + tsdy <= bottomy))))

if not ((highx + tsdx < minx) or (highx + tsdx > maxx) or (highy + tsdy < miny) or (highy + tsdy > maxy)) ` and not spawning outside screen edges

DisplayMorgs(highx + tsdx, highy + tsdy)                                                                ` then display morg on screen

ScreenScanned()

`CalcSpawnTime(tcday)                ` Calculate time for next morg spawn

CalcSpawnTime(spawndiff)

spawntimer = timer()

exitfunction

endif

endif ` if tcity

next i

if sprite exist(highspr) then set sprite diffuse highspr, sprred, sprgreen, sprblue

ScreenScanned()

endif ` if pairfound

`CalcSpawnTime(tcday)

CalcSpawnTime(spawndiff)

spawntimer = timer()

endif ` if timer() - (seconds)

endif ` if timer() - (flashtime)

endfunction ` SpawnMorg()

function SelectPair()

pairfound = 0

cityck = tcity(xscan, yscan)

if cityck >= tssprbeg and cityck <=tssprend ` If tombstone found

highspr = cityck

highx = xscan : highy = yscan

for i = 1 to 8                                          ` Check if it has a pair

tsdx = around(i).dx

tsdy = around(i).dy

cityck = tcity(highx + tsdx, highy + tsdy)

if cityck >= tssprbeg and cityck <=tssprend

pairfound = 1

set sprite diffuse highspr, hired, higreen, hiblue

exitfunction

endif

next i

endif ` if cityck

if pairfound = 0 and completed                              ` If whole screen has been scanned and there are no tombstone pairs found

if NoMorePairs()                                        ` ...Re-scan to ensure no new pairs have been created. If no pairs are found ...

if highspr

if sprite exist(highspr) then set sprite diffuse highspr, sprred, sprgreen, sprblue

endif

if morgnum = 0                                      ` and no enemies remain

ChangeColorGrid(gsprred, gsprgreen, gsprblue)

DisplayText()

sync

wait 1000

InitSprites()

inc tcscore, bonuspoints                        ` add bonus points to score

StartNewLevel()                                 ` then start a new level

endif

exitfunction

endif ` if NoMorePairs()

endif ` if pairfound = 0 and completed

ScreenScanned()

loop

endfunction ` SelectPair()

function DisplayMorgs(xxx, yyy)

inc morgnum

if morgnum <= maxmorgs ` Control max # of morgs on screen

for j = 1 to maxmorgs

if morg(j).mactive = 0                  ` Look for an inactive morg to reuse

morg(j).tcxx = xxx

morg(j).tcyy = yyy

morg(j).mactive = 1

morg(j).msprnum = SelAvailSpr()     ` Assign an available sprite #

play sprite morg(j).msprnum, begframe, endframe, morgframespd

sprite morg(j).msprnum, morg(j).tcxx * mltp, morg(j).tcyy * mltp, morgimg

show sprite morg(j).msprnum

if sprite exist(highspr) then set sprite diffuse highspr,sprred, sprgreen, sprblue

exitfunction

endif ` if morg(j)

next j

else

morgnum = maxmorgs

ChangeColorGrid(gsprred, gsprgreen, gsprblue)

if sprite exist(highspr) then set sprite diffuse highspr,sprred, sprgreen, sprblue

endif ` if morgnum

endfunction ` DisplayMorgs()

function SelAvailSpr()

availspr = 0 : k = 1

repeat

if morgsprite(k).available

availspr = morgsprite(k).sprnum

morgsprite(k).available = 0

endif

inc k

until availspr > 0

endfunction availspr ` SelAvailSpr()

function ScreenScanned()

completed = 0

inc xscan

if xscan > maxx

xscan = minx

inc yscan

if yscan > maxy

yscan = miny

completed = 1

endif

endfunction completed ` ScreenScanned()

function NoMorePairs()

nopairs = 1

for py = 1 to maxy

for px = 1 to maxx

cityck = tcity(px, py)

if cityck >= tssprbeg and cityck <=tssprend ` If tombstone found

for i = 1 to 8                                          ` Check if it has a pair

tsdx = around(i).dx

tsdy = around(i).dy

cityck = tcity(px + tsdx, py + tsdy)

if cityck >= tssprbeg and cityck <=tssprend then nopairs = 0 : exitfunction nopairs

next i

endif

next px

next py

endfunction nopairs ` NoMorePairs()

function SpeedUpMorg()

`if timer() > ctdntimr + countdown then morgtcspd = tcspd + 5

if timer() > ctdntimr + 1000

IncMorgSpeed(5)

`inc spawndiff

`CalcSpawnTime(spawndiff)

ctdntimr = timer()

endif

endfunction ` SpeedUpMorg

function Movemorg()

if morgnum > 0

if onemorgflag then SpeedUpMorg()

if timer() >= morgtctimer + morgtcspd

for mglp = 1 to maxmorgs

morgidx = mglp

if morg(morgidx).mactive

modx = Sgn(x - morg(morgidx).tcxx)                 ` determine delta x direction to chase ship (-1, 0, 1)

mody = Sgn(y - morg(morgidx).tcyy)                 ` determine delta y direction to chase ship (-1, 0, 1)

movexy = 0

CheckBlockedPath()

if not BlockedPath(modx,mody)                      ` If current path is not blocked (by tumbleweeds, grid or other morgs)

CompleteMove()                                 ` then go ahead and move morg(s)

ShipCollision()

endif

endif ` if morg(morgidx).mactive

next mglp

morgtctimer = timer()

endif ` if newmorgtimer >= ...

endif ` if morgnum > 0

endfunction ` Movemorg()

function CheckBlockedPath() ` new CheckSafeZone()

if BlockedPath(modx, mody)                                                     ` If morg path is blocked then...

if modx and mody

if (morg(morgidx).tcxx > x) then modx = -1 : mody = 0                 ` ...try moving horizontally toward ship (left-right)

if BlockedPath(modx, mody)

if (morg(morgidx).tcxx < x) then modx = 1 : mody = 0

if BlockedPath(modx, mody)

if (morg(morgidx).tcyy > y) then mody = -1 : modx = 0         ` ...or try moving vertically (up-down)

if BlockedPath(modx, mody)

if (morg(morgidx).tcyy < y) then mody = 1 : modx = 0

endif

endif `if modx and mody

endif `if BlockedPath

endfunction

function BlockedPath(modx,mody)

morgblocked = 0

CheckStone()                                       ` Check if tumbleweeds, tombstones or other morgs...

if blockedx() and blockedy() then morgblocked = 1  ` ...are blocking path

endfunction morgblocked

function CompleteMove()

movexy = int(rnd(1)) + 1                                               ` Select one of two directions x or y, since morg can't move diagonally

if (movexy = 1 and modx) or (modx and mody = 0)

if movexy = 1 then mody = 0

if mdx > maxx then morg(morgidx).tcxx = maxx else if mdx < minx then morg(morgidx).tcxx = minx else inc morg(morgidx).tcxx, modx

else

if (movexy = 2 and mody) or (mody and modx = 0)

if movexy = 2 then modx = 0

if mdy > maxy then morg(morgidx).tcyy = maxy else if mdy < miny then morg(morgidx).tcyy = miny else inc morg(morgidx).tcyy, mody

endif

play sprite morg(morgidx).msprnum, begframe, endframe, morgframespd

sprite morg(morgidx).msprnum,morg(morgidx).tcxx * mltp,morg(morgidx).tcyy * mltp, morgimg

play sound enemymovesound

endfunction ` CompleteMove()

function CheckStone()

tsmodx = modx

tsmody = mody

mdx = morg(morgidx).tcxx

mdy = morg(morgidx).tcyy

if tsmodx and tsmody

if blockedx() and blockedy()

exitfunction

else

movexy = int(rnd(1)) + 1

if movexy = 1 then  movingx() else movingy()

endif ` if blockedx()...

else

if tsmodx then movingx() else if tsmody then movingy()

endif ` if tsmodx and tsmody

endfunction ` CheckStone()

function blockedx()

rslt = 0

cityck =  tcity(mdx + tsmodx, mdy) ` if 1 - check if x+dx is open

if (cityck >= tssprbeg and cityck <= tssprend) or (cityck >= twsprbeg and cityck <= twsprend) or TouchMorgX() then rslt = 1

bmdx = morg(morgidx).tcxx + tsmodx        ` Add delta x to current morg position

bmdy = morg(morgidx).tcyy

if (((bmdx >= leftx) and (bmdx <= rightx)) and ((bmdy >= topy) and (bmdy <= bottomy))) then rslt = 1

endfunction rslt ` 1 means path is blocked in x direction

function blockedy()

rslt = 0

cityck =  tcity(mdx, mdy + tsmody)  ` check y+dy

if (cityck >= tssprbeg and cityck <= tssprend) or (cityck >= twsprbeg and cityck <= twsprend) or TouchMorgY() then rslt = 1

bmdx = morg(morgidx).tcxx

bmdy = morg(morgidx).tcyy + tsmody

if (((bmdx >= leftx) and (bmdx <= rightx)) and ((bmdy >= topy) and (bmdy <= bottomy))) then rslt = 1

endfunction rslt ` 1 means path is blocked in y direction

function movingx()

if  blockedx()     `if x is blocked

inc mdy, tsmody

mody = tsmody

modx = 0

else

inc mdx, tsmodx

modx = tsmodx

mody = 0

endif

endfunction ` movingx()

function movingy()

if blockedy()     ` if y is blocked

modx = tsmodx

mody = 0

else

mody = tsmody

modx = 0

endif

endfunction ` movingy()

function TouchMorgX()

tchmorgx = 0

for m = 1 to maxmorgs

if morg(m).mactive and m <> morgidx

if mdx + tsmodx = morg(m).tcxx and mdy = morg(m).tcyy then tchmorgx = 1 : exitfunction tchmorgx

endif

next m

endfunction tchmorgx

function TouchMorgY()

tchmorgy = 0

for m = 1 to maxmorgs

if morg(m).mactive and m <> morgidx

if mdy + tsmody = morg(m).tcyy and mdx = morg(m).tcxx then tchmorgy = 1 : exitfunction tchmorgy

endif

next m

endfunction tchmorgy

function MoveTweed()

if timer() >= twtctimer + twtcspd

if twonscreen = 0                       ` If no tumbleweeds...

if timer() >= twostctimer + 3000 and twshot < maxtweeds ` ... then wait a few seconds before re-spawning a new batch

DisplayTweeds()

endif

else

repeat

wdx = 0 : wdy = 0

inc i

if tweed(i).active

wx = tweed(i).twx : wy = tweed(i).twy

if wx = x

wdy = sgn(wy - y)       ` Reverse tumbleweed's y direction only if aligned on same column as ship

wdx = 0

else

if wy = y

wdx = sgn(wx - x)       ` Reverse tumbleweed's x direction only if aligned on same row as ship

wdy = 0

else

goto _skip

endif

if (wx + wdx < minx) or (wx + wdx > maxx) or (wy + wdy < miny) or (wy + wdy > maxy) then goto _skip ` Check edges

for j = 1 to maxmorgs

if morg(j).mactive

if (wx + wdx = morg(j).tcxx) and (wy + wdy = morg(j).tcyy) then goto _skip                  ` Check for morgs

endif

next j

if (((wx + wdx >= leftx) and (wx + wdx <= rightx)) and ((wy + wdy >= topy) and (wy + wdy <= bottomy))) then goto _skip ` Don't go inside safe grid

cityck = tcity(wx + wdx, wy + wdy)

if cityck > 0 then goto _skip

tcity(wx, wy) = 0                                                           ` Erase current sprite from coordinates before moving

sprite tweed(i).twsprnum, (wx + wdx) * mltp, (wy + wdy) * mltp, twimg       ` Move sprite to new position

tcity(wx + wdx, wy + wdy) = tweed(i).twsprnum                               ` Update city array with new sprite number at new coords

tweed(i).twx = wx + wdx                                                     ` Update tweed x and y coords

tweed(i).twy = wy + wdy

endif ` if tweed(i).active

_skip:

until i = weeds

endif ` if twonscreen = 0

twtctimer = timer()

endif

endfunction ` MoveTweed()

function GameTimeUpdate()

secs = elapsed + int((timer() - gametimer) / 1000)

if secs >= 60

inc mnts

secs = 0

elapsed = 0

if mnts >= tclevel and tclevel < maxtclevel

if onemorgflag = 0

IncMorgSpeed(5)                                     ` Speed up morg(s) every minute, if player plays for too long on a level

endif

gametimer = timer()

endif

if mnts = 60

inc hrs

mnts = 0

endif

endfunction  ` GameTimeUpdate()

function IncMorgSpeed(incspd)

dec morgtcspd, incspd

if morgtcspd < maxspd then morgtcspd = maxspd

inc spawndiff

CalcSpawnTime(spawndiff)

endfunction ` IncMorgSpeed()

function DisplayText()

`text 10,80,"FPS = "+str$(SCREEN FPS())

text 1, 1,GameRelease$                                                          ` v0.11 - 11/15/2010

text 1 * mltp,29 * mltp,"Population: "+str$(tcscore)

text 18 * mltp,29 * mltp,"Ships: "+str$(tclives)

text 34 * mltp,29 * mltp,"Day: "+str$(tcday)

if tclives = 0

text 13 * mltp,maxy * mltp,"Game Over"

sync

while keystate(59) = 0                                                      ` v0.11 - 11/15/2010 - Check for F1

text 1, 1,GameRelease$                                                  ` v0.11 - 11/15/2010

text 13 * mltp,maxy * mltp,"Game Over, F1 to re-start, Esc to quit"     ` v0.11 - 11/15/2010

text 1 * mltp,29 * mltp,"Population:"+str$(tcscore)

text 18 * mltp,29 * mltp,"Ships:"+str$(tclives)

text 34 * mltp,29 * mltp,"Day:"+str$(tcday)

sync

endwhile

endif

endfunction ` DisplayText()

function StartNewGame()                                                             ` v0.12 - 11/16/2010

tcday = 0 : tclives = numlives : tcscore = 0

ChangeColorGrid(gsprred, gsprgreen, gsprblue)

if sprite exist(highspr) then set sprite diffuse highspr, sprred, sprgreen, sprblue

for i = 1 to tssprend

if sprite exist(i) then hide sprite i

next i

cls

sprite shipsprite,x * mltp,y * mltp, shpimg : show sprite shipsprite

DisplayGrid()

panicbtn = 0 : diepanic = 0 : startlevel = 0 : exitblocked = 0 : gamerestarted = 1

endfunction ` StartNewGame()

function Shooting()

if angle = upangle then yth = -1 : xth = 0

if angle = rightangle then xth = 1 : yth = 0

if angle = downangle then yth = 1 : xth = 0

if angle = leftangle then xth = -1 : yth = 0

sddx = xth : sddy = yth

shx = x

shy = y

sprite bullsprite,shx * mltp,shy * mltp,bullimg

show sprite bullsprite

play sound shotsound

if timer() > bullettimer + bulltcspd

cityck = tcity(shx + sddx, shy + sddy)

if (cityck >= gridsprnum and cityck <= gridblkend) or (cityck >= tssprbeg and cityck <= tssprend) ` Check if bullet has hit any grid block or tombstone

hide sprite bullsprite

exit

endif

if xth                                                                                  ` Check if bullet is going left or right

if (shx + sddx < minx) or (shx + sddx > maxx) ` If so, check x boundaries

hide sprite bullsprite

exit

else

inc shx,sddx                                                                    ` keep moving to the left or right

endif

endif ` if xth

if yth                                                                                  ` Check if bullet is going up or down

if (shy + sddy < miny) or (shy + sddy > maxy) ` if so, check y boundaries

hide sprite bullsprite

exit

else

inc shy,sddy                                                                    ` keep moving up or down

endif

endif ` if yth

cityck = tcity(shx,shy)

if cityck >= twsprbeg and cityck <= twsprend ` If shot has hit a tumbleweed...

for i = 1 to weeds

if tweed(i).twsprnum = cityck                                                   ` ...find which sprite was hit and ...

tweed(i).active = 0                                                         ` ...de-activate it, to avoid unnecessary processing later

endif

next i

sprite bullsprite,0,0,bullimg

sprite cityck,0,0,twimg

hide sprite bullsprite

hide sprite cityck

tcity(shx,shy) = 0

dec twonscreen                                                                          ` Update # of tumbleweeds on screen

inc tcscore, tweedvalue                                                                 ` Update score

inc twshot                                                                              ` Keep track of tweeds shot down on level

if twshot >= twleech and tclevel < maxtclevel and onemorgflag =0 then IncMorgSpeed(5) ` Control leeching by speeding up game

if twonscreen = 0 then twostctimer = timer()                                            ` if no more tumbleweeds, start the tumbleweed re-spawning timer

exit

endif

for i = 1 to maxmorgs

if morg(i).mactive

if shx = morg(i).tcxx and shy = morg(i).tcyy                                    ` If shot has hit a morg...

hide sprite morg(i).msprnum

morg(i).mactive = 0

for j = 1 to maxmorgs

if morgsprite(j).sprnum = morg(i).msprnum then morgsprite(j).available = 1  ` Make morg sprite available to reuse

next j

dec morgnum                                                                     ` Update # of morgs on screen

sprite bullsprite,0,0,bullimg

hide sprite bullsprite

inc tcscore, morgvalue                                                          ` Update score

morgck = i : AddDelTombstone()

exitfunction

endif

next i

sprite bullsprite,shx * mltp,shy * mltp,bullimg

bullettimer = timer()

DisplayText()    ` debug

sync

endif `if newbulltimer > bullettimer + bulltcspd

loop

endfunction `Shooting()

function AddDelTombstone()

if FoundTombstonePair(morg(morgck).tcxx, morg(morgck).tcyy) ` If a tombstone pair is found around the morg that was just killed

DeletePair(paironex, paironey, pairtwox, pairtwoy)      ` delete pair of tombstones

DisplayMorgs(pairtwox, pairtwoy)                        ` and spawn a morg

else

AddTombstone(morg(morgck).tcxx, morg(morgck).tcyy)      ` if no pair was found, add a tombstone where the morg was killed

endif

endfunction ` AddDelTombstone()

function FoundTombstonePair(curx, cury)  ` Parameters curx, cury are the coordinates where morg was killed

` When a morg is killed, two things may happen:

` 1 - If there's a tombstone pair next to the morg just killed, or a morg is between a pair of tombstones, then this pair is eliminated and a new morg is spawned.

` 2 - If there's either a single tombstone or no tombstone next to the killed morg, then a single tombstone is generated at the spot the morg was killed, no morg is spawned.

` This function  will return 1 when a tombstone pair was found next to the killed morg, or if the killed morg was in between two tombstones.

` Function will return 0 when no tombstone pairs are found next to the killed morg.

firstfound = 0                                                  ` One tombstone found flag

delpairfound = 0                                                ` Pair of tombstones found flag

widx = 1

while firstfound = 0 and widx <= 8 ` Look for the 1st tombstone next to the morg

tsdx = around(widx).dx

tsdy = around(widx).dy

cityck = tcity(curx + tsdx, cury + tsdy)

if cityck >= tssprbeg and cityck <= tssprend

firstfound = 1                                          ` If found...

paironex = curx + tsdx                                  ` save the x,y coordinates for 1st tombstone

paironey = cury + tsdy

endif

inc widx :

endwhile

if firstfound = 0 then exitfunction delpairfound

widx = 1

while delpairfound = 0 and widx <= 8

tsdx = around(widx).dx

tsdy = around(widx).dy

cityck = tcity(curx + tsdx, cury + tsdy)                            ` Check for the second tombstone next to the morg

if  not (((curx + tsdx) = paironex) and ((cury + tsdy) = paironey)) ` skip the coords where 1st tombstone was already found

if (cityck >= tssprbeg and cityck <= tssprend)

delpairfound = 1

pairtwox = curx + tsdx

pairtwoy = cury + tsdy

endif

inc widx

endwhile

if delpairfound = 0                                                     ` If a second tombstone wasn't found around the morg...

widx = 1

while delpairfound = 0 and widx <= 8

tsdx = around(widx).dx

tsdy = around(widx).dy

curxdx = paironex + tsdx                                        ` ...check for the second tombstone next to the first tombstone

curydy = paironey + tsdy

cityck = tcity(curxdx, curydy)

if (cityck >= tssprbeg and cityck <= tssprend)

delpairfound = 1

pairtwox = curxdx                                           ` if found, then save the x,y coordinates for 2nd tombstone

pairtwoy = curydy

endif

inc widx

endwhile

endif ` if delpairfound = 0

endfunction delpairfound ` FoundTombstonePair()

function AddTombstone(xxx, yyy)

inc tssprend

tcity(xxx,yyy) = tssprend

sprite tssprend, xxx * mltp, yyy * mltp,4

show sprite tssprend                                                    `0.12 - 11/16/2010

size sprite tssprend, xsize, ysize

offset sprite tssprend, xoffst, yoffst

UpdateGridExits(xxx,yyy,1)

if AllExitsBlocked() and InsideGrid(x,y)                                ` Teleport ship outside the grid if all exits get blocked when ship is inside - `v0.12 - 11/16/2010

exitblocked = 1

Panic()

endif

endfunction ` AddTombstone()

function DeletePair(x1 ,y1, x2, y2)

delete sprite tcity(x1,y1)

delete sprite tcity(x2,y2)

tcity(x1,y1) = 0

tcity(x2,y2) = 0

UpdateGridExits(x1,y1,0) : UpdateGridExits(x2,y2,0)

if (highx = x1 and highy = y1) or (highx = x2 and highy = y2)

ChangeColorGrid(gsprred, gsprgreen, gsprblue)

if sprite exist(highspr) then set sprite diffuse highspr,sprred, sprgreen, sprblue

`CalcSpawnTime(tcday)                            ` Calculate time for next morg spawn

CalcSpawnTime(spawndiff)

spawntimer = timer()

endif

endfunction ` DeletePair()

function UpdateGridExits(tsxx,tsyy,blkstatus)

for i = 1 to 12

if tsxx = gridexit(i).xc and tsyy = gridexit(i).yc

gridexit(i).blocked = blkstatus

exitfunction

endif

next i

endfunction ` UpdateGridExits()

function AllExitsBlocked()

allblocked = 1

for i = 1 to 12

if gridexit(i).blocked = 0

allblocked = 0

exitfunction allblocked

endif

next i

endfunction allblocked ` AllExitsBlocked()

function InsideGrid(ix, iy)                 `v0.12 - 11/16/2010

inside = 0

if (((ix >= leftx) and (ix <= rightx)) and ((iy >= topy) and (iy <= bottomy)))

inside = 1

endif

endfunction inside ` InsideGrid()

function TeleportShip()

foundmorg = 0

inside = 0

repeat

x = rnd(maxx)

y = rnd(maxy)

cityck = tcity(x,y)

inside = InsideGrid(x,y)            `v0.12 - 11/16/2010

for i = 1 to maxmorgs

if morg(i).mactive

if x =  morg(i).tcxx and y = morg(i).tcyy

foundmorg = 1

endif

next i

until x <= maxx and x >= miny and y <= maxy and y >= miny and cityck = 0 and foundmorg = 0 and inside = 0

sprite shipsprite,x * mltp,y * mltp,shpimg

endfunction `TeleportShip()

function Panic()

if panicbtn or diepanic or startlevel or exitblocked `or gamerestarted

`if music playing(gamesound) then pause music gamesound               ` v0.13 - 11/19/2010

if diepanic

play sound diesound

dec tclives

endif

if panicbtn or exitblocked

play sound spawnsound

if panicbtn then dec tcscore, panicpenalty

if tcscore < 0 then tcscore = 0

endif

if AllExitsBlocked()

TeleportShip()

else

x = grid(0).tcxx + 3                                                    ` ship's spawn coordinates

y = grid(15).tcyy - 3

angle = upangle                                                         ` ship facing up

rotate sprite shipsprite, angle

sprite shipsprite,x * mltp,y * mltp,shpimg

endif ` if AllExitsBlocked()

if not gamerestarted

DisplayText() : sync

wait 500

endif

elapsed = secs

if tclives = 0

StartNewGame()                                                              ` v0.12 - 11/16/2010

StartNewLevel()

endif

while not (spacekey() or upkey() or downkey() or leftkey() or rightkey() or joystick fire a() or joystick y() = 1000 or joystick y() = -1000 or joystick x() = -1000 or joystick x() = 1000)

DisplayText()                                                          ` Pause game until player moves or fires

sync

endwhile

if downkey() or joystick y() = 1000 then angle = downangle : xth = 0 : yth = 1

if leftkey() or joystick x() = -1000 then angle = leftangle : xth = -1 : yth = 0

if rightkey() or joystick x() = 1000 then angle = rightangle : xth = 1 : yth = 0

rotate sprite shipsprite, angle

sprite shipsprite,x * mltp,y * mltp,shpimg

panicbtn = 0

diepanic = 0

startlevel = 0

exitblocked = 0

if gamerestarted

InitTimers()

gamerestarted = 0

endif

gametimer = timer()

`       if music paused(gamesound) then resume music gamesound                     ` v0.13 - 11/19/2010

endif

endfunction `Panic

function InitArrays()

restore _directiondata

for i = 1 to 8

read around(i).dx, around(i).dy

next i

_directiondata:

data 0,-1,1,-1,1,0,1,1,0,1,-1,1,-1,0,-1,-1

endfunction ` InitArrays

function InitMorgs()

for i = 1 to maxmorgs

morgsprite(i).sprnum = morgsprbeg + i - 1

morgsprite(i).available = 1

morg(i).mactive = 0

next i

endfunction `InitMorgs()

function InitTimers()

tctimer = timer()       ` Ship movement timer

shottimer = timer()     ` Rate of fire timer

bullettimer = timer()   ` Bullet speed timer

morgtctimer = timer()   ` Morg movement timer

twtctimer = timer()     ` Tumbleweed movement timer

twostctimer = timer()   ` Tumbleweed re-spawning timer

spawntimer = timer()    ` Morg spawn timer

gametimer = timer()     ` Game level timer

hrs = 0 : mnts = 0 : secs = 0 : elapsed = 0

endfunction ` InitTimers()

function StartNewLevel()

randomize timer()

`a = rnd(bkcc)

`color backdrop rgb(bkcolor(a).bkred, bkcolor(a).bkgreen, bkcolor(a).bkblue)

color backdrop rgb(209,174,102)

sync

for tcx = 1 to maxx

for tcy = 1 to maxy

tcity(tcx,tcy) = 0                  ` Clear map

next tcy

next tcx

inc tclives                                 ` Add one life

inc tcday                                   ` Increase level (day)

tclevel = tcday

spawndiff = tcday

if tclevel > maxtclevel

tclevel = maxtclevel                    ` tclevel is used to control the max # of tombstones on screen as well as game object speeds.

endif

`CalcSpawnTime(tcday)                        ` Calculate time for next morg spawn, based on day (level)

CalcSpawnTime(spawndiff)                    ` Calculate time for next morg spawn, based on day (level)

DisplayGrid()                               ` Display safe zone grid

InitMorgs()                                 ` Reset morg parameters

DisplayTombstones()                         ` Display Tombstones

DisplayTweeds()                             ` Display Tumbleweeds

ResetGridExits()                            ` Unblocks any blocked grid exits

x = grid(0).tcxx + 3                        ` Reset ship's starting coordinates

y = grid(15).tcyy - 3

tcspd = 60 - tclevel + 1.5                  ` Ship movement speed - lower = faster

morgtcspd = tcspd * (3 - tclevel * .05)     ` Milliseconds timer to control speed of enemy - lower = faster

`maxspd = tcspd + 5                          ` Max Morg speed (never faster than ship)

maxspd = tcspd                              ` Max Morg speed

twtcspd = 200 + tclevel * 10                ` Tumbleweed movement speed

morgnum = 0                                 ` Reset # of morgs on screen

xscan = 1 : yscan = 1                       ` Index variables to search for tombstone pairs

startlevel = 1                              ` Set new-level flag

onemorgflag = 0                             ` Reset flag that indicates there's one morg left

twshot = 0                                  ` Reset number of tumbleweeds shot down

leechflag = 0                               ` Resets flag that indicates if leeching is occurring (killing more than a specific # of tweeds specified in twleech constant)

`color backdrop rgb(bkcolor(a).bkred, bkcolor(a).bkgreen, bkcolor(a).bkblue)

`bdred = bkcolor(a).bkred :  bdgreen = bkcolor(a).bkgreen :  bdblue = bkcolor(a).bkblue

if gamerestarted = 0

Panic()                                     ` Place the ship on screen and wait for player to start

InitTimers()                                ` Reset all timers after player starts, then continue gameplay

endif

remstart

if music exist(gamesound)                               ` v0.13 11/19/2010

stop music gamesound

play music gamesound

set music volume gamesound,10

endif

remend

set joystick deadzone 50

endfunction ` StartNewLevel()

function CalcSpawnTime(gamelevel)

if gamelevel < 10

seconds = 13 - gamelevel + 3                ` Decrease seconds to spawn a new morg

flashtime = seconds - 3                     ` Time to start warning the upcoming spawn

endif

if gamelevel >= 10 and gamelevel < 15

seconds = rnd(4) + 3

flashtime = seconds - (rnd(seconds) + 1)

endif

if gamelevel >= 15

seconds = rnd(6) + 1

flashtime = seconds

endif

endfunction

function InitSprites()

for i = tssprdel to tssprend

if sprite exist(i) then delete sprite i

next i

endfunction ` InitSprites()

function LoadMedia()

` *** Sprites ***

xoffst = xsize / 2 : yoffst = ysize / 2        ` Sprite offsets

load image "media\spaceship01.png", shpimg     ` Ship - sprite 1

sprite shipsprite,x * mltp,y * mltp, shpimg

size sprite shipsprite,xsize,ysize

offset sprite shipsprite,xoffst,xoffst

load image "media\block.jpg", blockimg, 1         ` Safe area block - sprites 2-17

load image "media\bullet01.bmp", bullimg, 1    ` Bullet

sprite bullsprite,0,0,bullimg

size sprite bullsprite,xsize / 2, ysize / 2

offset sprite bullsprite,xoffst / 2, yoffst / 2

set sprite diffuse bullsprite, 255, 0, 0

hide sprite bullsprite

load image "media\cactus.png", tmbstoneimg, 1   ` Tombstone - sprites 301-up

create animated sprite morgsprbeg,"media\morg.bmp",3,2, morgimg    ` Morg - Sprites 201- up

size sprite morgsprbeg,xsize,ysize

offset sprite morgsprbeg, xoffst, yoffst

for i = morgsprbeg + 1 to morgsprbeg + maxmorgs - 1

clone sprite morgsprbeg, i

next i

load image "media\tumbleweed.png",twimg,1     ` Tumbleweeds - sprites 101-120

` *** Sounds ***

load sound "media\sounds\respawn.wav",spawnsound           ` Hyperspace panic sound (Return Key)

load sound "media\sounds\fire01.wav",shotsound             ` Schooner ship shot fired sound (Space Bar)

load sound "media\sounds\die.wav",diesound                 ` Schooner ship destroyed sound

load sound "media\sounds\enemy_move.wav",enemymovesound    ` Enemy is moving

`   set sound volume enemymovesound, 100

`load music "media\sounds\goodbadugly.mid",gamesound        ` Background music - v0.13 11/19/2010

endfunction ` LoadMedia()

function DisplayGrid()

gx = int(maxx / 2) - 4

gy = int(maxy / 2) - 3

gridblkcnt = 0 : grd = 0

for xxx = 1 to 4

for yyy = 1 to 4

grd = gridsprnum + gridblkcnt

sprite grd,(gx + xxx * 2) * mltp, (gy + yyy * 2) * mltp,2

`          size sprite grd, xsize, ysize

show sprite grd

grid(gridblkcnt).tcxx = gx + xxx * 2

grid(gridblkcnt).tcyy = gy + yyy * 2

tcity(grid(gridblkcnt).tcxx, grid(gridblkcnt).tcyy) = grd     ` Array storing objects on screen

offset sprite grd,xsize / 2, ysize / 2

inc gridblkcnt

next yyy

next xxx

gridblkend = gridsprnum + gridblkcnt - 1                           ` Determine the last sprite #

` Safe zone grid x and y boundaries

leftx = grid(0).tcxx                                               ` Upper and lower left corner x coordinate

rightx = grid(15).tcxx                                             ` Upper and lower right corner x coordinate

topy = grid(0).tcyy                                                ` Upper left and upper right y coordinate

bottomy = grid(15).tcyy                                            ` Lower left and lower right y coordinate

endfunction ` DisplayGrid()

Function DisplayTombstones()

restore _tstonedata

tssprcount = tssprbeg - 1

numstones = tclevel * 4 + 1

for i = 1 to numstones * 2

tsspnum = tssprbeg + i - 1

read tx, ty

tcity(tx,ty) = tsspnum

sprite tsspnum, tx * mltp, ty * mltp,tmbstoneimg

show sprite tsspnum

size sprite tsspnum, xsize, ysize

offset sprite tsspnum, xoffst, yoffst

inc tssprcount

next i

sprred = sprite red(tssprbeg)

sprgreen = sprite green(tssprbeg)

sprblue = sprite blue(tssprbeg)

tssprend =  tssprcount

tssprdel = tssprend

_tstonedata:

data 8,4,7,5,9,15,8,15,19,8,20,9,32,17,31,18,20,25,19,25     ` Level 1: 5 pairs, 20 coordinates

data 15,4,15,5,34,4,33,5,29,25,30,26,5,24,5,25               ` Level 2: +4 pairs = 9 pairs, 16 new coordinates

data 5,9,6,9,31,9,30,10,32,22,33,22,8,20,7,21                ` Level 3: +4 pairs = 13 pairs

data 4,13,3,14,23,3,24,3,25,16,26,16,21,21,20,22             ` Level 4: +4 pairs = 17 pairs

data 10,7,11,8,33,13,34,13,25,22,26,23,11,22,12,23           ` Level 5: +4 pairs = 21 pairs

data 10,11,9,12,28,12,29,13,35,24,34,25,9,25,8,26            ` Level 6: +4 pairs = 25 pairs

data 11,17,12,18,22,5,21,6,35,19,36,20,24,25,23,26           ` Level 7: +4 pairs = 29 pairs

data 4,17,4,18,27,6,28,6,28,19,27,20,15,24,15,25             ` Level 8: +4 pairs = 33 pairs

data 13,13,13,14,25,8,24,9,34,15,35,16,15,22,16,22           ` Level 9: +4 pairs = 37 pairs

endfunction  ` DisplayTombstones()

function DisplayTweeds()                                         `v0.12 - 11/16/2010

i = 1

twonscreen = 0

while i <= weeds

_rndcoords:

tweedx = rnd(maxx)

tweedy = rnd(maxy)

if InsideGrid(tweedx,tweedy) then goto _rndcoords

if tweedx <= maxx and tweedx >= miny and tweedy <= maxy and tweedy >= miny

foundmorg = 0

for j = 1 to maxmorgs

if morg(j).mactive

if tweedx =  morg(j).tcxx and tweedy = morg(j).tcyy

foundmorg = 1

endif

next j

if foundmorg = 1 or tcity(tweedx,tweedy) > 0  or (tweedx = x and tweedy = y)

goto _rndcoords

else

sprite twsprbeg + i - 1,tweedx * mltp,tweedy * mltp,twimg

show sprite twsprbeg + i - 1

size sprite twsprbeg + i - 1, xsize, ysize

offset sprite twsprbeg + i - 1, xoffst, xoffst

set sprite diffuse twsprbeg + i - 1,0,128,0

tcity(tweedx,tweedy) = twsprbeg + i - 1

tweed(i).twx = tweedx

tweed(i).twy = tweedy

tweed(i).twsprnum = twsprbeg + i - 1

tweed(i).active = 1

inc twonscreen

inc i

endif

else

goto _rndcoords

endif ` if tweedx ...

endwhile

twsprend = twsprbeg + twonscreen - 1

endfunction ` DisplayTweeds()

function NoMorgsAround()

nomorgs = 1

for ii = 1 to maxmorgs

if morg(ii).mactive

if  ((highx + tsdx) = morg(ii).tcxx) and ((highy + tsdy) = morg(ii).tcyy)

nomorgs = 0

exitfunction nomorgs

endif

next ii

endfunction nomorgs

function ChangeColorGrid(rr,gg,bb)

for i = 0 to 15

blksprnum = tcity(grid(i).tcxx, grid(i).tcyy)

set sprite diffuse blksprnum, rr, gg, bb

next i

endfunction ` ChangeColorGrid

function LoadBkColors()

restore _bkcolordata

bkcc = 0

repeat

read rd, grn, bl

bkcolor(bkcc).bkred = rd

bkcolor(bkcc).bkgreen = grn

bkcolor(bkcc).bkblue = bl

inc bkcc

until (rd = 0 and grn = 0 and bl = 0)

dec bkcc,2

_bkcolordata:

data 167,84,116,119,130,91,13,113,23,86,78,234

data 13,70,116,117,46,24,78,100,23,42,74,101

data 0,0,0

endfunction ` LoadBkColors()

function ResetGridExits()

restore _exitdata

for i = 1 to 12

read grindex, dx,dy

gridexit(i).xc = grid(grindex).tcxx + dx

gridexit(i).yc = grid(grindex).tcyy + dy

gridexit(i).blocked = 0

next i

_exitdata:

data 0,1,-1, 0, -1, 1, 1, -1, 1, 2, -1, 1

data 3,1,1,4, 1, -1, 7, 1, 1, 8, 1, -1

data 11, 1, 1, 12, 1, 1, 13, 1, 1, 14, 1, 1

endfunction ` ResetGridExits()

Function Sgn( NumValue as Float )

ValueSign as integer

if NumValue = 0

ValueSign = 0

else

if NumValue < 0

ValueSign = -1

else

ValueSign = 1

endif

EndFunction ValueSign

_end:

end

Download

Please login to download

Comments

No comments yet.

Author Name:	CSL
CodeBase Entries:	3

CodeBase - Tombstone City - game from the 80's now in DBPro

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments