TheGameCreators - CodeBase

Return to the CodeBase listing

Category: Bitmap

Version: 1.4

Information

Uploaded: 30th Aug 2003 09:45

Modified: 17th Sep 2005 06:13

Author: IanM

Summary

Fast floodfill routine. Now amended to work correctly in both 16 & 32 bit mode.

Full Description

Floodfill routine, with all the performance enhancements that I could think of.<br /> <br /> This version contains a 'memory' to keep track of where it has previously painted in the current fill, so that you don't paint there again. This is far faster than rechecking pixels on the bitmap, although it is a bit memory intensive.

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

type __FloodFillType

Initialised as integer

CoverColour as integer

BitmapWidth as integer

BitmapHeight as integer

endtype

global __FloodFillGlobal as __FloodFillType

#constant __SpanListSize 15

type __FillSpan

Left as integer

Right as integer

endtype

global dim __FilledSpans() as __FillSpan

global dim __FilledSpansCount() as integer

function FloodFill(x,y,c)

__FloodFillGlobal.BitmapWidth=bitmap width()-1

__FloodFillGlobal.BitmapHeight=bitmap height()-1

__InitialiseFillSpan()

if x >= 0 and x <= __FloodFillGlobal.BitmapWidth

if y >= 0 and y <= __FloodFillGlobal.BitmapHeight

lock pixels

__FloodFillGlobal.CoverColour = point(x,y)

if __FloodFillGlobal.CoverColour <> c

ink c,0

__FloodLoop(x,y)

endif

unlock pixels

endif

endfunction

function __FloodLoop(x as integer,y as integer)

local Left as integer

local Right as integer

local SpanSize as integer

for Left=x-1 to 0 step -1

if point(Left,y) <> __FloodFillGlobal.CoverColour then exit

next Left

inc Left

for Right=x+1 to __FloodFillGlobal.BitmapWidth

if point(Right,y) <> __FloodFillGlobal.CoverColour then exit

next Right

` draw this line

box Left,y,Right,y+1

` and remember it

__AddFillSpan(y,Left-1,Right+1)

` Fill upwards

if y > 0

dec y

x=Left

while x < Right

SpanSize=__CheckFillSpan(x,y)

if SpanSize = 0

if point(x,y) = __FloodFillGlobal.CoverColour

__FloodLoop(x,y)

endif

inc x

else

inc x,SpanSize

endif

endwhile

inc y

endif

` Fill downwards

if y < __FloodFillGlobal.BitmapHeight

inc y

x=Left

while x < Right

SpanSize=__CheckFillSpan(x,y)

if SpanSize = 0

if point(x,y) = __FloodFillGlobal.CoverColour

__FloodLoop(x,y)

endif

inc x

else

inc x,SpanSize

endif

endwhile

endif

endfunction

function __InitialiseFillSpan()

local i as integer

if __FloodFillGlobal.Initialised = 0

` First time called, create the arrays - bigger than we should ever need

undim __FilledSpans()

global dim __FilledSpans(__SpanListSize,2048) as __FillSpan

undim __FilledSpansCount()

global dim __FilledSpansCount(2048) as integer

__FloodFillGlobal.Initialised=1

else

` Subsequent call, just reset the spans we'll be using

for i=__FloodFillGlobal.BitmapHeight to 0 step -1

__FilledSpansCount(i)=0

next i

endif

endfunction

function __AddFillSpan(y as integer,Left as integer,Right as integer)

local i as integer

i=__FilledSpansCount(y)

if i < __SpanListSize

__FilledSpans(i, y).Left=Left

__FilledSpans(i, y).Right=Right

inc __FilledSpansCount(y)

endif

endfunction

function __CheckFillSpan(x as integer,y as integer)

local i as integer

for i=__FilledSpansCount(y)-1 to 0 step -1

if x >= __FilledSpans(i, y).Left

if x < __FilledSpans(i, y).Right then exitfunction __FilledSpans(i, y).Right-x

endif

next i

endfunction 0

Download

Please login to download

Comments

No comments yet.

Author Name:	IanM
CodeBase Entries:	26

CodeBase - Floodfill

Information

Summary

Full Description

DarkBASIC Professional Source Code

Download

Screen Shot

Author

Comments