TheGameCreators - CodeBase - capture a selected part of the desktop to an image

Return to the CodeBase listing

Category: Display

Version: 1.0

Information

Uploaded: 8th Feb 2004 09:41

Modified: 2nd Apr 2006 09:45

Author: the_winch

Summary

uses api calls to capture part of the desktop and puts it in the desired image

Full Description

Useage get_screen(image number, left, top, right, bottom) get_screen(5,100,150,200,300) will capture the desktop from 100,150 to 200,300 and put it in image 5 If any part of the capture area is outside the desktop it will be white in the image.

DarkBASIC Professional Source Code

` This code was downloaded from The Game Creators

` It is reproduced here with full permission

` http://www.thegamecreators.com

function get_screen(image as integer,x1 as integer,y1 as integer,x2 as integer,y2 as integer)

`copies a selected area of the desktop to an image

`the_winch : http://winch.pinkbile.com : thewinch@gmail.com

local hwnd as integer    :`desktop window handle

local dc as integer      :`device context for entire desktop window

local x,y,in,pix as integer

local dll_user,dll_gdi as integer :`dll numbers

local mem as integer : `memblock number

`load dlls

dll_user = get_screen_free_dll() : load dll "user32.dll",dll_user

dll_gdi = get_screen_free_dll()  : load dll "gdi32.dll",dll_gdi

`get the desktop handle and device context for entire window

hwnd = call dll(dll_user,"GetDesktopWindow")

dc = call dll(dll_user,"GetWindowDC",hwnd)

mem = get_screen_free_memblock() : `get a free memblock to write the image data to

`make sure x2-x1 and y2-y2 is postitive

if x1 > x2 then in = x2 : x2 = x1 : x1 = in

if y1 > y2 then in = y2 : y2 = y1 : y1 = in

`make the memblock used to hold image info

make memblock 1,12+(((x2-x1)*(y2-y1))*4)

write memblock dword 1,0,x2-x1

write memblock dword 1,4,y2-y1

write memblock dword 1,8,32

`fill the memblock with the desktop image

in = 12

for y = y1 to y2-1

for x = x1 to x2-1

pix = call dll(dll_gdi,"GetPixel",dc,x,y)  :`get the desktop pixel colour

pix = rgb(rgbb(pix),rgbg(pix),rgbr(pix))   :`windows gives us the colour info in rgb format where dbpro memblocks use bgr so swap r and b arround

write memblock dword mem,in,pix            :`write the pixel to the memblock

inc in,4

next x

next y

`convert the memblock to image and cleanup

make image from memblock image,mem

delete memblock mem

delete dll dll_user

delete dll dll_gdi

endfunction

function get_screen_free_memblock()

`finds a free memblock

local i,stop as integer

repeat

inc i

if memblock exist(i) = 0 then stop = 1

until stop = 1

endfunction i

function get_screen_free_dll()

`finds a free dll slot

local i,stop as integer

repeat

inc i

if i < 256 then if dll exist(i)=0 then stop = 1

until stop = 1 or i > 255

if i > 255 then i = 0

endfunction i

Download

Please login to download

Comments

No comments yet.

Author Name:	the_winch
CodeBase Entries:	7

CodeBase - capture a selected part of the desktop to an image